VB编写记事本的源码

[Visual Basic] 纯文本查看 复制代码

需要3个控件
Microsoft Common Dialog Control 6.0
Microsoft Rich Textbox Control 6.0
Microsoft Windows Common Controls 6.0

'声明查找变量
Dim sFind As String
'声明文件类型
Dim FileType, FiType As String
'声明文字是否改变
Dim change As Boolean

'初始化程序
Private Sub Form_Load()
    '设置程序启动时的大小
    Me.Height = 8000
    Me.Width = 11640
    
    change = False
    'StatusBar1.Panels(6).Text = Time
End Sub

'设置编辑框的位置和大小
Private Sub Form_Resize()
    On Error Resume Next '出错处理
    RichTextBox1.Top = 20
    RichTextBox1.Left = 20
    RichTextBox1.Height = ScaleHeight - 400
    RichTextBox1.Width = ScaleWidth - 40
End Sub

Private Sub Form_Unload(Cancel As Integer)

    If change Then
    Dim result As Integer
    result = MsgBox("您已经做了修改，是否保存？", vbYesNoCancel, "提示")
        If (vbCancel = result) Then
            Cancel = True
            Exit Sub
        Else
            If vbYes = result Then
                mnuSave_Click
            End If
        End If
        
    End If
End Sub

Private Sub mnuAbout_Click()
    
    MsgBox "我的记事本 Ver1.0 版权所有(C) 2010 By：安静", vbOKOnly, "关于"
    
End Sub

Private Sub mnuCopy_Click()

    Clipboard.Clear
    Clipboard.SetText RichTextBox1.SelText

End Sub

Private Sub mnuCut_Click()

    Clipboard.Clear
    Clipboard.SetText RichTextBox1.SelText
    RichTextBox1.SelText = ""
    
End Sub

Private Sub mnuExit_Click()

    End

End Sub

Private Sub mnuFind_Click()

    sFind = InputBox("请输入要查找的字、词：", "查找内容", sFind)
    RichTextBox1.Find sFind

End Sub

Private Sub mnuFont_Click()
    
    
    CommonDialog1.Flags = cdlCFBoth Or cdlCFEffects
    '显示“字体”对话框。
    CommonDialog1.ShowFont
    '根据用户的选择来设置文本属性。
    RichTextBox1.SelFontName = CommonDialog1.FontName
    RichTextBox1.SelFontSize = CommonDialog1.FontSize
    RichTextBox1.SelBold = CommonDialog1.FontBold
    RichTextBox1.SelItalic = CommonDialog1.FontItalic
    RichTextBox1.SelUnderline = CommonDialog1.FontUnderline
    RichTextBox1.SelStrikeThru = CommonDialog1.FontStrikethru
    RichTextBox1.SelColor = CommonDialog1.Color
    
    
    
End Sub

Private Sub RichTextBox1_Change()

    change = True
    StatusBar1.Panels(1).Text = "正在编辑文档：" & CommonDialog1.FileName
    
End Sub

'设置弹出式菜单（即在编辑框中单击鼠标右键时弹出的动态菜单）
Private Sub RichTextBox1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 Then
        PopupMenu mnuEdit, vbPopupMenuLeftAlign
    Else
        Exit Sub
    End If
End Sub

Private Sub mnuFindOn_Click()

    RichTextBox1.SelStart = RichTextBox1.SelStart + RichTextBox1.SelLength + 1
    RichTextBox1.Find sFind, , Len(RichTextBox1)

End Sub

Private Sub mnuOpen_Click()

    CommonDialog1.Filter = "文本文档(*.txt)|*.txt|RTF文档(*.rtf)|*.rtf|所有文件(*.*)|*.*"
    CommonDialog1.ShowOpen
    RichTextBox1.Text = "" '清空文本框
    FileName = CommonDialog1.FileName
    RichTextBox1.LoadFile FileName
    Me.Caption = "我的记事本：" & FileName

End Sub

Private Sub mnuPaste_Click()
    
    RichTextBox1.SelText = Clipboard.GetText
    
End Sub

Private Sub mnuSave_Click()
    CommonDialog1.Filter = "文本文档(*.txt)|*.txt|RTF文档(*.rtf)|*.rtf|所有文件(*.*)|*.*"
    CommonDialog1.ShowSave
    FileType = CommonDialog1.FileTitle
    FiType = LCase(Right(FileType, 3))
    FileName = CommonDialog1.FileName
    Select Case FiType
    Case "txt"
        RichTextBox1.SaveFile FileName, rtfText
    Case "rtf"
        RichTextBox1.SaveFile FileName, rtfRTF
    Case "*.*"
        RichTextBox1.SaveFile FileName
    End Select
    Me.Caption = "我的记事本：" & FileName
End Sub

Private Sub mnuSelecAll_Click()

    RichTextBox1.SelStart = 0
    RichTextBox1.SelLength = Len(RichTextBox1.Text)

End Sub

Private Sub mnuUsage_Click()

    On Error GoTo handler
    RichTextBox1.LoadFile "Readme.txt", rtfText '请写好Readme.txt文件并存入程序所在文件夹中
    Me.Caption = "我的记事本：" & "使用说明"
    Exit Sub
handler:
    MsgBox "使用说明文档可能已经被移除，请与作者联系。", vbOKOnly, " 错误信息"

End Sub

Private Sub munNew_Click()

    RichTextBox1.Text = "" '清空文本框
    FileName = "未命名"
    Me.Caption = FileName
    StatusBar1.Panels(1).Text = "正在打开文件" & "《" & CommonDialog1.FileTitle & "》"
    
End Sub









                                                                                                                  by：安静 2010.7.31

有点眼熟呢？？？？

楼上的是花心萝卜吧，哈哈

新手啊 看到好长的代码